Creating a triggered email in Marketing Cloud is not an easy task. But once mastered, the process doesn’t take too much time.

What do you need?

There are 3 steps that you need to follow in this exact order:

1. Create a Triggered Send Data Extension
2. Create an email with Content Builder
3. Create a Triggered Send

Let’s examine each step separately.

Step 1: Create a Triggered Send Data Extension

In order to create a Triggered Send Data Extension, you need to use Contact Builder.

Choose Create From Template as the creation method and choose TriggeredSendDataExtension as the template.

You’ll notice that 2 fields are now mandatory: SubscriberKey and EmailAddress. For the sake of this tutorial, let’s add 2 more fields:

FirstName	Text	50	Nullable
Language	Text	2	Nullable

Step 2: Create an email

In order to create a Triggered Send Data Extension, you need to use Content Builder. Make it as simple as possible and use the following code for later customization:

%%[ 
	VAR @Greeting
	IF Language == "EN" THEN 
		SET @Greeting = "Hello"
	ELSE
		SET @Greeting = "Bonjour"
	ENDIF 
]%%
<h1>%%=v(@Greeting)=%% %%=v(FirstName)=%%</h1>

Step 3: Create a Triggered Send

In order to create a Triggered Send, you need to use Email Studio.

The process is straightforward, just make sure to choose the Email and the Triggered Send Data Extension you created previously.

If you get any errors when trying to save, it usually means that your Email contains AMPscript that uses different field names than what you have in your Triggered Send Data Extension.

The last step is to Start the Triggered Send by clicking on the Start/Restart button on the top.

Now, let’s take a note of the External Key of our Triggered Send and move forward to the coding.

Triggering an email with AMPscript

At first, let’s define some variables, where the SubsciberKey is a simple timestamp for the purpose of this tutorial and the TriggerSendExternalKey is the External Key generated by the creation of our Triggered Send.

SET @SubscriberKey = Format(SystemDateToLocalDate(NOW()), "yyddMMhhmmss")
SET @EmailAddress = "misterblue@mail.com"
SET @Language = "EN"
SET @TriggerSendExternalKey = "12345"

Then, let’s proceed with creating the TriggeredSend, Subscriber and Attribute objects. The names of the variables that we are setting are not important. In most cases you will not re-use them and therefore try to keep them as short as possible, unlike what I’m doing in this example.

Note that the names of the object properties are the same as in our Triggered Send Data Extension.

/* Specify the external key of the TriggerSend */
SET @TriggerSend = CreateObject("TriggeredSend")
SET @TriggerSendDefinition = CreateObject("TriggeredSendDefinition")
SetObjectProperty(@TriggerSendDefinition, "CustomerKey", @TriggerSendExternalKey)
SetObjectProperty(@TriggerSend, "TriggeredSendDefinition", @TriggerSendDefinition)

/* Specify the email address and the subscriber key */
SET @TriggerSendSubscriber = CreateObject("Subscriber")
SetObjectProperty(@TriggerSendSubscriber, "EmailAddress", @EmailAddress) 
SetObjectProperty(@TriggerSendSubscriber, "SubscriberKey", @SubscriberKey) 

/* Fill out the Language field in the TriggerSend data extension */
SET @TriggerSendLanguage = CreateObject("Attribute")
SetObjectProperty(@TriggerSendLanguage, "Name", "Language")
SetObjectProperty(@TriggerSendLanguage,"Value", @Language)
AddObjectArrayItem(@TriggerSend, "Attributes", @TriggerSendLanguage)

/* Fill out the FirstName field in the TriggerSend data extension */
SET @TriggerSendFirstName = CreateObject("Attribute")
SetObjectProperty(@TriggerSendFirstName, "Name", "FirstName")
SetObjectProperty(@TriggerSendFirstName,"Value", @FirstName)
AddObjectArrayItem(@TriggerSend, "Attributes", @TriggerSendFirstName)

AddObjectArrayItem(@TriggerSend, "Subscribers", @TriggerSendSubscriber) 

The only thing left to do is to use InvokeCreate method, which will send the data to the Triggered Send. The Triggered send will then write the data in the Triggered Send Data Extension and send the email.

SET @TriggerSend_statusCode = InvokeCreate(@TriggerSend, @TriggerSend_statusMsg, @errorCode) 

Let’s also add some basic error log if something goes wrong.

IF @TriggerSend_statusCode != "OK" THEN
	OUTPUTLINE(CONCAT("Status: ",@TriggerSend_statusMsg," / Code: ",@errorCode))
ENDIF

Voilà! If everything was executed correctly, it works like magic!

Full code

%%[

	SET @SubscriberKey = Format(SystemDateToLocalDate(NOW()), "yyddMMhhmmss")
	SET @EmailAddress = "misterblue@mail.com"
	SET @Language = "EN"
	SET @TriggerSendExternalKey = "12345"

	/* Specify the external key of the TriggerSend */
	SET @TriggerSend = CreateObject("TriggeredSend")
	SET @TriggerSendDefinition = CreateObject("TriggeredSendDefinition")
	SetObjectProperty(@TriggerSendDefinition, "CustomerKey", @TriggerSendExternalKey)
	SetObjectProperty(@TriggerSend, "TriggeredSendDefinition", @TriggerSendDefinition)

	/* Specify the email address and the subscriber key */
	SET @TriggerSendSubscriber = CreateObject("Subscriber")
	SetObjectProperty(@TriggerSendSubscriber, "EmailAddress", @EmailAddress) 
	SetObjectProperty(@TriggerSendSubscriber, "SubscriberKey", @SubscriberKey) 

	/* Fill out the Language field in the TriggerSend data extension */
	SET @TriggerSendLanguage = CreateObject("Attribute")
	SetObjectProperty(@TriggerSendLanguage, "Name", "Language")
	SetObjectProperty(@TriggerSendLanguage,"Value", @Language)
	AddObjectArrayItem(@TriggerSend, "Attributes", @TriggerSendLanguage)

	/* Fill out the FirstName field in the TriggerSend data extension */
	SET @TriggerSendFirstName = CreateObject("Attribute")
	SetObjectProperty(@TriggerSendFirstName, "Name", "FirstName")
	SetObjectProperty(@TriggerSendFirstName,"Value", @FirstName)
	AddObjectArrayItem(@TriggerSend, "Attributes", @TriggerSendFirstName)

	AddObjectArrayItem(@TriggerSend, "Subscribers", @TriggerSendSubscriber)  

	SET @TriggerSend_statusCode = InvokeCreate(@TriggerSend, @TriggerSend_statusMsg, @errorCode) 

	IF @TriggerSend_statusCode != "OK" THEN
		OUTPUTLINE(CONCAT("Status: ",@TriggerSend_statusMsg," / Code: ",@errorCode))
	ENDIF

]%%

Troubleshooting

Your code doesn’t work? Let’s figure out why!

Can’t create a Triggered Send?

1. Did you specify the correct Email, Data Extension and choose the correct List with an add/update subscribers option?
2. Check your Email and test it with a record from your Triggered Send Data Extension.

Email not sent?

1. Check the Triggered Send Data Extension. If your record exists, the email should arrive shortly, unless it got queued for some reason, in which case I advise you to restart the Triggered Send from the Email Studio.
2. Check the status of your Triggered Send, it might be on Pause.
3. The person might be blacklisted or unsubscribed from the List you chose when creating the Triggered Send.

Error 500?

1. Does the External Key exist? Please check the Trigger Send in the Email Studio.
2. The Trigger Send object property name doesn’t exist in the Triggered Send Data Extension or is in an incorrect format (in short, don’t try to write letters in a Boolean type field).
3. Syntax error. Please, try to debug AMPscript to see what went wrong.

Have I missed anything?

Please poke me with a sharp comment below or use the contact form.